搜索:
向播放器添加插件
增加功能
使用说明
插件制作示例
监听动作插件
修改右键
修改/增加右键菜单
修改,添加右键

监听动作插件

在查阅该文之前需要了解的内容如下:

插件制作

swf文件调用和监听播放器函数事件示例

AS3API控制函数列表

AS3API监听函数列表

正文:

该插件是用来监听播放器的各种动作。制作好后放在全局自定义元件区域,也即style.xml中的节点<custom>中的<swf>节点里:下面是制作方式。

一:打开flash,版本:CC,新建一个1x1的空舞台后,按F9调用出代码编辑器界面。

二:将下列代码复制进去:

import flash.display.Sprite;
import ckplayeraction.Element;
import flash.text.TextField;
import flash.utils.Timer;
import flash.events.TimerEvent;

var ck: Object = null;
var myName: String = "";
var prompt: Sprite = null;
var ptimer: Timer = null;
var isPause: Boolean = true;
function setAppObj(app: Object = null,name:String=""): void {
	ck = app;
	myName = name;
	ck.addListener("full", fullHandler); //监听是否全屏
	ck.addListener("volume", volumeHandler); //监听音量
	ck.addListener("paused", pausedHandler); //监听音量
	ck.addListener("muted", mutedHandler); //监听静音
}
function fullHandler(b: Boolean = false): void {
	if (b) {
		addPrompt("全屏");
	}
	else {
		addPrompt("退出全屏");
	}
}
function volumeHandler(n:Number = 0): void {
	if (n > 0) {
		addPrompt("音量:" + Math.round(n*100) + "%");
	}
	else {
		addPrompt("静音");
	}
}
function pausedHandler(b: Boolean = false): void {
	if (b) {
		if (!isPause) {
			addPrompt("暂停");
		}
	}
	else {
		addPrompt("播放");
		isPause = false;
	}
}
function mutedHandler(b: Boolean = false): void {
	if (b) {
		addPrompt("静音");
	}
}
function addPrompt(title: String = ""): void { //共用的建议提示函数
	if (!title) {
		return;
	}
	if (prompt) {
		removeChild(prompt);
		prompt = null;
	}
	if (ptimer) {
		if (ptimer.running) {
			ptimer.stop();
		}
		ptimer.removeEventListener(TimerEvent.TIMER, ptimerHandler);
		ptimer = null;
	}
	var st: TextField = ckplayeraction.Element.newTitle({
		text: title
	});
	prompt = ckplayeraction.Element.newSprite({
		width: st.width + 30,
		height: st.height + 10,
		bgAlpha: 80,
		radius:5
	});
	prompt.alpha = 0.8;
	st.x = (prompt.width - st.width) * 0.5;
	st.y = (prompt.height - st.height) * 0.5-2;
	prompt.x = -(prompt.width * 0.5);
	prompt.y = -(prompt.height * 0.5);
	addChild(prompt);
	prompt.addChild(st);
	ptimer = new Timer(2000, 0);
	ptimer.addEventListener(TimerEvent.TIMER, ptimerHandler);
	ptimer.start();
}
function ptimerHandler(event: TimerEvent): void {
	ptimer.removeEventListener(TimerEvent.TIMER, ptimerHandler);
	ptimer = null;
	if (prompt) {
		removeChild(prompt);
		prompt = null;
	}
}

三:保存任意文件名称(可以是中文或英文)。保存完后按CTRL+ENTER组合键生成swf文件,这个文件就可以使用了。关于安装可以看下方的文章

建议了解以下相关内容:

自定义元件的说明以及安装方法

Powered by ckplayer.com
Copyright©ckplayer,2011-2017( 苏ICP备11026158号 )